Another fluxus friday adventure…

; a simple realtime cloth simulation model
(clear)
(texture (load-texture "test2.png"))

(define rez 25) ; resolution of nurbs patch
(define dist 0.1) ; the desired spring length

(define p ; setup the nurbs primitive
    (with-state
        (backfacecull 0) ; we wanna see the back
        (ambient 0.2)
        (rotate (vector -90 0 0))
        (scale (vector 8 4 4))
        (build-nurbs-plane (- rez 1) (- rez 1))))

(with-primitive p (pdata-add "vel" "v"))

(define (spring a b) ; return vector trying to keep the length
    (let ((d (vsub a b))) ; between the two input points constant
        (vmul d (- dist (vmag d)))))

(every-frame
    (with-primitive p
        (pdata-index-map! ; for each control vertex
            (lambda (i v p)
                (let ((x (modulo i rez)) ; get the x and y from
                      (y (quotient i rez))) ; the index
                    (if (> x 0)
                        ; we want to 'pin' the top row of cvs 
                        (vmul (vadd v
                                (spring p (pdata-ref "p" (- i 1)))
                                (if (< x (- rez 1)) ; deal with the edges
                                    (spring p (pdata-ref "p" (+ i 1)))
                                    (vector 0 0 0))
                                (if (> y 0)
                                    (spring p (pdata-ref "p" (- i rez)))
                                    (vector 0 0 0))
                                (if (< y (- rez 1))
                                    (spring p (pdata-ref "p" (+ i rez)))
                                    (vector 0 0 0))
                                ; add constant gravity 
                                (vector 0 0 -0.001))
                            0.995) v)))
            "vel" "p")
        (pdata-op "+" "p" "vel") ; add velocity to the vertex positions
        (recalc-normals 1))) 

; setup the lights
(light-diffuse 0 (vector 0 0 0))
(define l (make-light 'point 'free))
(light-diffuse l (vector 1 1 1))
(light-position l (vector 10 300 -10))
(light-specular l (vector 1 1 1))
(light-ambient l (vector 0.3 0.3 0.3))

0 2

Trying to reinstate “fluxus friday” where I reserve some time for livecoding or fluxus hacking at the end of the week. First up, a new way of making fuzzy blobs in fluxus – particle aggregation. I like the analogue feel to it – reminds me of the voxels from last year. I also found this for syntax highlighting lisp for blog posts.

; a blurry particle aggregation example
(clear)
(hint-depth-sort)
(texture (load-texture "splat.png"))
(blend-mode 'src-alpha 'one)
(define p (build-particles 500))
(define r 1)

; setup the particle primitive
(with-primitive p
    (pdata-add "a" "f") ; 1 if we have attached to another particle
    (pdata-add "vel" "v") ; velocity array
    (pdata-map! (lambda (a) 0) "a") ; init to zero
    (pdata-set! "a" 0 1)
    (pdata-map! (lambda (c) 0.1) "c") ; init the colour
    (pdata-map!
        (lambda (p)
            (vmul (hsrndvec) r)) ; space out in a hollow sphere
        "p")
    (pdata-map!
        (lambda (vel p)
            (vector 0.02 0 0)) ; init velocities
        "vel" "p")
    (pdata-set! "p" 0 (vector 0 0 0)))

; check particle n against all others and return #t if we
; are close enouth to another to aggregate
(define (collide? n)
    (let ((np (pdata-ref "p" n)))
        (pdata-index-fold
            (lambda (i p a r)
                (if (and (not r) (not (zero? a)) (not (eq? i n)) (< (vdist p np) 0.05))
                    #t r))
            #f "p" "a")))

(every-frame
    (with-primitive p
        (pdata-map!
            (lambda (p vel a)
                (if (zero? a) ; if we're not attached
                    (if (> (vmag p) r) ; and we are outside the sphere
                        (vmul (hsrndvec) r) ; reset position
                        (vadd p vel)) ; move with velocity
                     p))
            "p" "vel" "a")
        (pdata-index-map! ; check all particles and set a if they
            (lambda (i a) ; have attached to any others
                (if (and (zero? a) (collide? i)) 1 a))
            "a")))

0 1

Part one of my pixelache experience was on the ice surrounded island of Suomenlinna, where Gabor and I spent 3 days working on fluxus. With the help of the puredyne sprint team we got the debian packaging working on launchpad – which is Ubuntu’s system for organising software packages and making sure they build on the various architectures and Ubuntu OS versions. We now have a fluxus ppa so people running a debian based system can directly get updates from us with apt-get upgrade.

We also spent a little time discussing the situation with proprietary graphics card drivers and Linux. This has recently become a personal matter, as my graphics card is no longer supported by ATI for current Linux kernels. We talked about avoiding locked away features as artistic constraint, and looked at people trying to do something about this like the xorg crack pushers and phoronix. One plan is to make the more cutting edge xorg code availible as a puredyne package so we can quickly test these free software drivers for installations and performances.

0 0